Away3DLite 使用 Collada

Away3DLite 1.0 出一陣子了：
http://away3d.com/away3d-lite-v1-0-fastest-and-smallest-3d-engine-in-flash

號稱很小、很快，因為使用了 Flash Player 10 提供的 3D 語法，所以限制一定要使用 FP10 瀏覽才行。

以下，我作一個簡單的範例，載入一個 Collada 格式的 *.dae 模型檔案，這個 *.dae 可由各種 3D 建模軟體加上外掛輸出而成，或是像我偷懶去網路上找現成的借用一下。

Collada Test Model Bank: https://collada.org/owl/
我沒研究這個地方的版權說明，總之，借用者別用作營利用途就好～

範例原始碼：

package
{
 import away3dlite.core.base.Object3D;
 import away3dlite.loaders.Collada;
 import away3dlite.materials.WireframeMaterial;
 import away3dlite.templates.BasicTemplate;
 
 import flash.events.Event;
 import flash.events.MouseEvent;
 import flash.net.URLLoader;
 import flash.net.URLRequest;

 [SWF(width=640, height=480)]
 public class Away3DLite_TestCollada extends BasicTemplate
 {
  public function Away3DLite_TestCollada()
  {
   super();
  }
  
  private const ROTATION_DY_MAX:Number = 5;
  private var rotation_dy:Number = 0;
  
  private const ROTATION_DX_MAX:Number = 5;
  private var rotation_dx:Number = 0;
  
  private var _myCollada:Object3D

  override protected function onInit():void{
   camera.z = 0;
   camera.zoom = 300;
   
   view.mouseEnabled3D = false;
   
   var loader:URLLoader = new URLLoader();
   loader.addEventListener(Event.COMPLETE, onColladaLoaded);
   loader.load(new URLRequest("collada.dae"));
  }  
  
  private function onColladaLoaded(e:Event):void{
   addColladaObj((e.currentTarget as URLLoader).data);
   
   stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   stage.addEventListener(MouseEvent.MOUSE_WHEEL, onMouseWheel);
  }
  
  private function addColladaObj(data:*):void{
   var collada:Collada = new Collada();
   collada.material = new WireframeMaterial();
   _myCollada = collada.parseGeometry(data);
   
   scene.addChild(_myCollada);
  }
  
  private function onMouseMove(e:MouseEvent):void{
   var dmx:Number = mouseX - width/2;
   dmx = Math.min(Math.max(dmx, -width/2), width/2);
   rotation_dy = ROTATION_DY_MAX * (dmx / (width/2));
   
   var dmy:Number = mouseY - height/2;
   dmy = Math.min(Math.max(dmy, -height/2), height/2);
   rotation_dx = ROTATION_DX_MAX * (dmy / (height/2));
  }
  
  private function onMouseWheel(e:MouseEvent):void{
   camera.z += (10 * e.delta);
   camera.z = Math.min(camera.z, 0);
  }
  
  override protected function onPreRender():void{
   if(_myCollada!=null){
    _myCollada.rotationY += rotation_dy;
    _myCollada.rotationX += rotation_dx;
   }
  }
  
 }
}

載入 *.dae 後，可用滑鼠在畫面上移動，根據滑鼠 x, y 座標來使模型沿著 y 軸旋轉、x 軸旋轉，另外可用滑鼠滾輪控制 camera 的前進後退。

看效果：
http://sites.google.com/site/benrbchang/Away3DLite-Collada